当前位置:网站首页>Arduino IDE搭建ESP8266开发环境,文件下载过慢解决方法 | ESP-01制作WiFi开关教程,改造宿舍灯

Arduino IDE搭建ESP8266开发环境,文件下载过慢解决方法 | ESP-01制作WiFi开关教程,改造宿舍灯

2020-11-08 14:37:03 蔡子CaiZi

1. Arduino IDE配置ESP8266环境

参考:https://www.jianshu.com/p/cb0274d612b5

首先从 Arduino 官网 下载最新版本的 Arduino IDE 软件并安装。
安装完成以后,进入首选项(Preferences),找到附加开发板管理器地址(Additional Board Manager URLs),并在其后添加如下信息:

http://arduino.esp8266.com/stable/package_esp8266com_index.json

再点击确定(OK);

 之后点击工具 - 开发板 - 开发板管理器,进入开发板管理器界面:

输入esp, 找到 esp8266 并安装;

笔者在安装过程中发现下载速度太慢,于是去esp8266 arduino的github页面(https://github.com/esp8266/Arduino/releases)下载了压缩包(笔者用的2.6.0),再放进C盘就可以了,下面是详细步骤:

https://github.com/earlephilhower/esp-quick-toolchain/releases?after=3.0.0-gnu5

笔者将这6个压缩包放至了百度网盘,解压后放进这个文件夹;

链接:https://pan.baidu.com/s/1hX45SsujWOyPKyntA6fDkQ
提取码:8266 

 然后在开发板管理器上,输入esp, 找到 esp8266 即可快速安装~

2. 烧写程序方法

参考:http://www.elecfans.com/dianzichangshi/20171123584883.html

将ESP8266与USB-TTL按照下面的接线图进行连接。最好使用下面这种免冷启动的。

 

 

 

 

esp8266-01板的arduino烧写方式分享

  UTXD—–RXD

  URXD—–TXD

  CH_PD—-3.3v

  VCC——-3.3V

  GND——GND

  GPIO0—–GND

将连接好ESP8266的USB-TTL插在电脑上,对IDE进行如下设置:

你可以上传ESP8266WIFI的相关程序了。

  注意事项

  1.esp8266-01板对电压的要求很高,烧写时电源一定要采用3.3V左右。

  2.如果代码无法上传,并显示警告,请检查USB-TTL是否良好(某些USB-TTL烧写时无法打开串口,导致上传失败)。

  3.ESP8266与USB-TTL需要RX,TX交叉连接。

  4.CH_PD这个引脚无论是烧程序也好,烧完程序应用也好,都要接3.3V。

  5.GPIO0这个引脚在烧程序的时候必须接GND(接低电平),烧完程序后想要进行应用的话,必须将这个引脚拉高或者悬空。

3. WiFi控制舵机程序

/*
* nodemcu引脚对应数字:
* 16=D0;
* 4=D2;
* 0=D3;
* 2=D4;
* 14=D5;
* 12=D6;
* 13=D7;
* 15=D8;
* 3=D9;
* 1=D10;
* ESP-01引脚对应数字:
* GPIO2 --2 舵机 ->模拟输出
* GPIO16--16
*/

 
#include <ESP8266WiFi.h>
#include <Servo.h>
 
 
#ifndef STASSID
#define STASSID "填写你的WiFi名称"    //WiFi名称
#define STAPSK  "填写你的WiFi密码"  //WiFi密码
#endif

#define ANGLE_ON  76    //开灯时的舵机角度
#define ANGLE_OFF 153   //关灯时的舵机角度
#define ANGLE_NONE 110  //置空时的舵机角度

const char* ssid = STASSID;
const char* password = STAPSK;
int angle=ANGLE_NONE;//舵机角度
Servo myservo;  //创造一个servo结构体
 
//创建服务器实例,指定要监听的端口为80端口
WiFiServer server(80);
 
void setup() {
  Serial.begin(115200);
  myservo.attach(16); //舵机信号线,接analogIn脚
  myservo.write(angle);// 0~180°
  //连接WiFi
  Serial.println();
  Serial.println();
  Serial.print(F("WiFi start connect "));//用F函数将会把字符串放入RAM中,输出至串口
  Serial.println(ssid);
 
  WiFi.mode(WIFI_STA);//设置为接收WiFi模式
  WiFi.begin(ssid, password);
 
  while (WiFi.status() != WL_CONNECTED) {
    
    delay(500);
    Serial.print(F("."));
  }
  Serial.println();
  Serial.println(F("WiFi已连接!"));
 
  //开启模块的服务器
  server.begin();
  Serial.println(F("模块服务端已开启!"));
 
  //打印模块的IP地址
  Serial.println(WiFi.localIP());
}
 
void loop() {
  //监测客户端是否连接
  WiFiClient client = server.available();
  if (!client) {
    return;//如果未连接就重新循环监测
  }
//  Serial.println(F("new client"));
 
  client.setTimeout(1000); // default is 1000
 
  //读取请求内容的第一行
  String req = client.readStringUntil('\r');
  Serial.println(F("请求: "));
  Serial.println(req);
 
  //匹配 请求-->信号变量
  if (req.indexOf(F("/gpio/0")) != -1) {
    angle = ANGLE_ON;//如果/gpio/0在请求内容中,发出开灯的信号
    myservo.write(angle);// 0~180°
    delay(1000);
    myservo.write(ANGLE_NONE);//将舵机重新置空,以免一直受力损坏
  } 
  else if (req.indexOf(F("/gpio/1")) != -1) {
    angle = ANGLE_OFF;
    myservo.write(angle);// 0~180°
    delay(1000);
    myservo.write(ANGLE_NONE);//将舵机重新置空,以免一直受力损坏
  } 
  else {
    Serial.println(F("无效请求"));
  }
  //读取或忽略余下的请求内容
  while (client.available()) {
    client.read();
  }
  
  //向客户端发送回答,HTML网页代码内容
  //nagle算法会将它们分组为一个数据包
  client.print(F("<!DOCTYPE html>\r\n<html xmlns='http://www.w3.org/1999/xhtml'>\r\n"));
  client.print(F("<head>\r\n<meta charset='utf-8'/>\r\n<title>智能卧室灯</title>\r\n"));
  client.print(F("<style type='text/css'>.state{text-align:center;font-size:80px;}"));
  client.print(F(".on{text-align:center;font-size:200px;alink='#1a9e5f'}.off{text-align:center;font-size:200px;alink='#da4f43'}"));
  client.print(F("</style><body><div class='state'>灯状态:"));
  client.print((angle>ANGLE_NONE) ? F("关</div>") : F("开</div>"));
  client.print(F("<br><br><div class='on'><a href='http://"));//<br>换行
  client.print(WiFi.localIP());
  client.print(F("/gpio/0'>开</a></div><br><br><div class='off'><a href='http://"));
  client.print(WiFi.localIP());
  client.print(F("/gpio/1'>关</a></div></body></html>"));
 
  // 客户端实际上将被“刷新”,然后断开连接
  // 当函数返回并且“客户端”对象被销毁时
  // 刷新=确保书面数据被服务端接收
  Serial.println(F("客户端已挂起!"));
}

通过串口监视器(115200波特率)获取到路由器分配给NodeMCU的IP地址,即可通过访问网址来控制开/关灯 。

比如笔者这里读取到的IP为192.168.0.143,那么

开灯时手机上访问的网址为http://192.168.0.143/gpio/0;

关灯时手机上访问的网址为http://192.168.0.143/gpio/1。

(手机需要和NodeMCU在同一个路由器下,即连接的是同一个WiFi)

需要注意的是ESP8266可能连不上手机热点和5GWiFi,WiFi名字也最好不要带中文。

版权声明
本文为[蔡子CaiZi]所创,转载请带上原文链接,感谢
https://www.cnblogs.com/cai-zi/p/13942615.html